The Perl Toolchain Summit 2025 Needs You: You can help 🙏 Learn more

DROLSKY / DateTime-TimeZone-2.65 / lib / DateTime / TimeZone / OffsetOnly.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
—
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154

              
package DateTime::TimeZone::OffsetOnly;
use strict;
use warnings;
use namespace::autoclean;
our $VERSION = '2.65';
use parent 'DateTime::TimeZone';
use DateTime::TimeZone::UTC;
use Params::ValidationCompiler 0.13 qw( validation_for );
use Specio::Library::String;
{
    my $validator = validation_for(
        name             => '_check_new_params',
        name_is_optional => 1,
        params           => {
            offset => {
                type => t('NonEmptyStr'),
            },
        },
    );
    sub new {
        my $class = shift;
        my %p     = $validator->(@_);
        my $offset = DateTime::TimeZone::offset_as_seconds( $p{offset} );
        die "Invalid offset: $p{offset}\n" unless defined $offset;
        return DateTime::TimeZone::UTC->new unless $offset;
        my $self = {
            name   => DateTime::TimeZone::offset_as_string($offset),
            offset => $offset,
        };
        return bless $self, $class;
    }
}
sub is_dst_for_datetime {0}
sub offset_for_datetime       { $_[0]->{offset} }
sub offset_for_local_datetime { $_[0]->{offset} }
sub is_utc {0}
sub short_name_for_datetime { $_[0]->name }
sub category {undef}
sub STORABLE_freeze {
    my $self = shift;
    return $self->name;
}
sub STORABLE_thaw {
    my $self = shift;
    shift;
    my $serialized = shift;
    my $class = ref $self || $self;
    my $obj;
    if ( $class->isa(__PACKAGE__) ) {
        $obj = __PACKAGE__->new( offset => $serialized );
    }
    else {
        $obj = $class->new( offset => $serialized );
    }
    %$self = %$obj;
    return $self;
}
1;
# ABSTRACT: A DateTime::TimeZone object that just contains an offset
__END__
=pod
=encoding UTF-8
=head1 NAME
DateTime::TimeZone::OffsetOnly - A DateTime::TimeZone object that just contains an offset
=head1 VERSION
version 2.65
=head1 SYNOPSIS
  my $offset_tz = DateTime::TimeZone->new( name => '-0300' );
=head1 DESCRIPTION
This class is used to provide the DateTime::TimeZone API needed by DateTime.pm,
but with a fixed offset.  An object in this class always returns the same
offset as was given in its constructor, regardless of the date.
=head1 USAGE
This class has the same methods as a real time zone object, but the
C<category()> method returns undef.
=head2 DateTime::TimeZone::OffsetOnly->new ( offset => $offset )
The value given to the offset parameter must be a string such as "+0300".
Strings will be converted into numbers by the
C<DateTime::TimeZone::offset_as_seconds()> function.
=head2 $tz->offset_for_datetime( $datetime )
No matter what date is given, the offset provided to the constructor is always
used.
=head2 $tz->name()
=head2 $tz->short_name_for_datetime()
Both of these methods return the offset in string form.
=head1 SUPPORT
Bugs may be submitted at L<https://github.com/houseabsolute/DateTime-TimeZone/issues>.
=head1 SOURCE
The source code repository for DateTime-TimeZone can be found at L<https://github.com/houseabsolute/DateTime-TimeZone>.
=head1 AUTHOR
Dave Rolsky <autarch@urth.org>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2025 by Dave Rolsky.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
The full text of the license can be found in the
F<LICENSE> file included with this distribution.
=cut