From Code to Community: Sponsoring The Perl and Raku Conference 2025 Learn more

LTHEISEN / Footprintless-1.29 / lib / Footprintless / CommandRunner / IPCRun.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
—
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140

              
use strict;
use warnings;
package Footprintless::CommandRunner::IPCRun;
$Footprintless::CommandRunner::IPCRun::VERSION = '1.29';
# ABSTRACT: An implementation of Footprintless::CommandRunner using IPC::Run
# PODNAME: Footprintless::CommandRunner::IPCRun
use parent qw(Footprintless::CommandRunner);
use Carp;
use IPC::Run;
use Log::Any;
my $logger = Log::Any->get_logger();
sub _run_options {
    my ( $self, $runner_options ) = @_;
    my @timeout;
    if ( $runner_options->{timeout} ) {
        @timeout = ( IPC::Run::timeout( $runner_options->{timeout} ) );
    }
    my $in = $runner_options->{in_handle} || \undef;
    my $out =
           $runner_options->{out_handle}
        || $runner_options->{out_callback}
        || \$self->{last_call}{stdout};
    my $err =
           $runner_options->{err_handle}
        || $runner_options->{err_callback}
        || \$self->{last_call}{stderr};
    return ( '<', $in, '>', $out, '2>', $err, @timeout );
}
sub _run {
    my ( $self, $command, $runner_options ) = @_;
    if ( $runner_options->{out_callback} || $runner_options->{err_callback} ) {
        my $out_callback = $runner_options->{out_callback};
        my $err_callback = $runner_options->{err_callback};
        my ( $out, $err );
        local $runner_options->{out_callback} = \$out if ($out_callback);
        local $runner_options->{err_callback} = \$err if ($err_callback);
        my $harness =
            IPC::Run::start( [ 'sh', '-c', $command ], $self->_run_options($runner_options) );
        my ( $last_part_out, $last_part_err ) = ( '', '' );
        eval {
            while ( $harness->pump() ) {
                if ($out_callback) {
                    my @lines = split( /\r?\n/, $last_part_out . $out, -1 );
                    $last_part_out = pop(@lines) || '';
                    &$out_callback($_) foreach (@lines);
                    $out = '';
                }
                if ($err_callback) {
                    my @lines = split( /\r?\n/, $last_part_err . $err, -1 );
                    $last_part_err = pop(@lines) || '';
                    &$err_callback($_) foreach (@lines);
                    $err = '';
                }
            }
            &$out_callback($last_part_out)
                if ( $out_callback && length($last_part_out) > 0 );
            &$err_callback($last_part_err)
                if ( $err_callback && length($last_part_err) > 0 );
        };
        my $error = $@;
        if ($error) {
            $logger->debugf( "callback exited early: %s", $error );
            $harness->kill_kill();
            die($error);
        }
    }
    else {
        IPC::Run::run( [ 'sh', '-c', $command ], $self->_run_options($runner_options) );
    }
    return $? >> 8;
}
1;
__END__
=pod
=head1 NAME
Footprintless::CommandRunner::IPCRun - An implementation of Footprintless::CommandRunner using IPC::Run
=head1 VERSION
version 1.29
=head1 DESCRIPTION
An implementation of L<Footprintless::CommandRunner> using C<IPC::Run>.
=head1 CONSTRUCTORS
=head2 new()
Constructs a new instance.
=head1 AUTHOR
Lucas Theisen <lucastheisen@pastdev.com>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2016 by Lucas Theisen.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=head1 SEE ALSO
Please see those modules/websites for more information related to this module.
=over 4
=item *
L<Footprintless|Footprintless>
=item *
L<Footprintless|Footprintless>
=item *
L<Footprintless::CommandRunner|Footprintless::CommandRunner>
=back
=cut