NAME

Encode - character encodings

SYNOPSIS

use Encode;

Table of Contents

Encode consists of a collection of modules which details are too big to fit in one document. This POD itself explains the top-level APIs and general topics at a glance. For other topics and more details, see the PODs below;

Name			        Description
--------------------------------------------------------
Encode::Alias         Alias defintions to encodings
Encode::Encoding      Encode Implementation Base Class
Encode::Supported     List of Supported Encodings
Encode::CN            Simplified Chinese Encodings
Encode::JP            Japanese Encodings
Encode::KR            Korean Encodings
Encode::TW            Traditional Chinese Encodings
--------------------------------------------------------

DESCRIPTION

The Encode module provides the interfaces between Perl's strings and the rest of the system. Perl strings are sequences of characters.

The repertoire of characters that Perl can represent is at least that defined by the Unicode Consortium. On most platforms the ordinal values of the characters (as returned by ord(ch)) is the "Unicode codepoint" for the character (the exceptions are those platforms where the legacy encoding is some variant of EBCDIC rather than a super-set of ASCII - see perlebcdic).

Traditionally computer data has been moved around in 8-bit chunks often called "bytes". These chunks are also known as "octets" in networking standards. Perl is widely used to manipulate data of many types - not only strings of characters representing human or computer languages but also "binary" data being the machines representation of numbers, pixels in an image - or just about anything.

When Perl is processing "binary data" the programmer wants Perl to process "sequences of bytes". This is not a problem for Perl - as a byte has 256 possible values it easily fits in Perl's much larger "logical character".

TERMINOLOGY

• character: a character in the range 0..(2**32-1) (or more). (What Perl's strings are made of.)

• byte: a character in the range 0..255 (A special case of a Perl character.)

• octet: 8 bits of data, with ordinal values 0..255 (Term for bytes passed to or from a non-Perl context, e.g. disk file.)

The marker [INTERNAL] marks Internal Implementation Details, in general meant only for those who think they know what they are doing, and such details may change in future releases.

PERL ENCODING API

$octets = encode(ENCODING, $string[, CHECK])

Encodes string from Perl's internal form into ENCODING and returns a sequence of octets. ENCODING can be either a canonical name or alias. For encoding names and aliases, see "Defining Aliases". For CHECK see "Handling Malformed Data".

For example to convert (internally UTF-8 encoded) Unicode string to iso-8859-1 (also known as Latin1),

$octets = encode("iso-8859-1", $unicode);

$string = decode(ENCODING, $octets[, CHECK])

Decode sequence of octets assumed to be in ENCODING into Perl's internal form and returns the resulting string. as in encode(), ENCODING can be either a canonical name or alias. For encoding names and aliases, see "Defining Aliases". For CHECK see "Handling Malformed Data".

For example to convert ISO-8859-1 data to UTF-8:

$utf8 = decode("iso-8859-1", $latin1);

[$length =] from_to($string, FROM_ENCODING, TO_ENCODING [,CHECK])

Convert in-place the data between two encodings. For example to convert ISO-8859-1 data to UTF-8:

from_to($data, "iso-8859-1", "utf-8");

and to convert it back:

from_to($data, "utf-8", "iso-8859-1");

Note that because the conversion happens in place, the data to be converted cannot be a string constant, it must be a scalar variable.

from_to() return the length of the converted string on success, undef otherwise.

UTF-8 / utf8

The Unicode consortium defines the UTF-8 standard as a way of encoding the entire Unicode repertoire as sequences of octets. This encoding is expected to become very widespread. Perl can use this form internally to represent strings, so conversions to and from this form are particularly efficient (as octets in memory do not have to change, just the meta-data that tells Perl how to treat them).

$octets = encode_utf8($string);

The characters that comprise string are encoded in Perl's superset of UTF-8 and the resulting octets returned as a sequence of bytes. All possible characters have a UTF-8 representation so this function cannot fail.

$string = decode_utf8($octets [, CHECK]);

The sequence of octets represented by $octets is decoded from UTF-8 into a sequence of logical characters. Not all sequences of octets form valid UTF-8 encodings, so it is possible for this call to fail. For CHECK see "Handling Malformed Data".

Listing available encodings

use Encode;
@list = Encode->encodings();

Returns a list of the canonical names of the available encodings that are loaded. To get a list of all available encodings including the ones that are not loaded yet, say

@all_encodings = Encode->encodings(":all");

Or you can give the name of specific module.

@with_jp = Encode->encodings("Encode::JP");

When "::" is not in the name, "Encode::" is assumed.

@ebcdic = Encode->encodings("EBCDIC");

To find which encodings are supported by this package in details, see Encode::Supported.

Defining Aliases

To add new alias to a given encoding, Use;

use Encode;
use Encode::Alias;
define_alias(newName => ENCODING);

After that, newName can be used as an alias for ENCODING. ENCODING may be either the name of an encoding or an encoding object

But before you do so, make sure the alias is nonexistent with resolve_alias(), which returns the canonical name thereof. i.e.

Encode::resolve_alias("latin1") eq "iso-8859-1" # true
Encode::resolve_alias("iso-8859-12")   # false; nonexistent
Encode::resolve_alias($name) eq $name  # true if $name is canonical

This resolve_alias() does not need use Encode::Alias and is exported via use encode qw(resolve_alias).

See Encode::Alias on details.

Encoding via PerlIO

If your perl supports PerlIO, you can use PerlIO layer to directly decode and encode via filehandle. The following two examples are totally identical by functionality.

# via PerlIO
open my $in,  "<:encoding(shiftjis)", $infile  or die;
open my $out, ">:encoding(euc-jp)",   $outfile or die;
while(<>){ print; }

# via from_to
open my $in,  $infile  or die;
open my $out, $outfile or die;
while(<>){ 
  from_to($_, "shiftjis", "euc", 1);
}

Unfortunately, not all encodings are PerlIO-savvy. You can check if your encoding is supported by PerlIO by perlio_ok method.

Encode::perlio_ok("iso-20220jp");        # false
find_encoding("iso-2022-jp")->perlio_ok; # false
use Encode qw(perlio_ok);                # exported upon request
perlio_ok("euc-jp")                      # true if PerlIO is enabled

For gory details, see Encode::PerlIO;

Handling Malformed Data

THE CHECK argument is used as follows. When you omit it, it is identical to CHECK = 0.

CHECK = Encode::FB_DEFAULT ( == 0)

If CHECK is 0, (en|de)code will put substitution character in place of the malformed character. for UCM-based encodings, <subchar> will be used. For Unicode, \xFFFD is used. If the data is supposed to be UTF-8, an optional lexical warning (category utf8) is given.

CHECK = Encode::DIE_ON_ERROR (== 1)

If CHECK is 1, methods will die immediately with an error message. so when CHECK is set, you should trap the fatal error with eval{} unless you really want to let it die on error.

CHECK = Encode::FB_QUIET

If CHECK is set to Encode::FB_QUIET, (en|de)code will immediately return proccessed part on error, with data passed via argument overwritten with unproccessed part. This is handy when have to repeatedly call because the source data is chopped in the middle for some reasons, such as fixed-width buffer. Here is a sample code that just does this.

my $data = '';
while(defined(read $fh, $buffer, 256)){
  # buffer may end in partial character so we append
  $data .= $buffer;
  $utf8 .= decode($encoding, $data, ENCODE::FB_QUIET);
  # $data now contains unprocessed partial character
}

CHECK = Encode::FB_WARN

This is the same as above, except it warns on error. Handy when you are debugging the mode above.

perlqq mode (CHECK = Encode::FB_PERLQQ)

For encodings that are implemented by Encode::XS, CHECK == Encode::FB_PERLQQ turns (en|de)code into perlqq fallback mode.

When you decode, '\xXX' will be placed where XX is the hex representation of the octet that could not be decoded to utf8. And when you encode, '\x{xxxx}' will be placed where xxxx is the Unicode ID of the character that cannot be found in the character repartoire of the encoding.

The bitmask

These modes are actually set via bitmask. here is how FB_XX are laid out. for FB_XX you can import via use Encode qw(:fallbacks) for generic bitmask constants, you can import via use Encode qw(:fallback_all).

                    FB_DEFAULT FB_CROAK FB_QUIET FB_WARN  FB_PERLQQ
DIE_ON_ERR    0x0001             X
WARN_ON_ER    0x0002                               X
RETURN_ON_ERR 0x0004                      X        X
LEAVE_SRC     0x0008
PERLQQ        0x0100                                        X

Unemplemented fallback schemes

In future you will be able to use a code reference to a callback function for the value of CHECK but its API is still undecided.

Defining Encodings

To define a new encoding, use:

use Encode qw(define_alias);
define_encoding($object, 'canonicalName' [, alias...]);

canonicalName will be associated with $object. The object should provide the interface described in Encode::Encoding If more than two arguments are provided then additional arguments are taken as aliases for $object as for define_alias.

See Encode::Encoding for more details.

Messing with Perl's Internals

The following API uses parts of Perl's internals in the current implementation. As such they are efficient, but may change.

is_utf8(STRING [, CHECK])

[INTERNAL] Test whether the UTF-8 flag is turned on in the STRING. If CHECK is true, also checks the data in STRING for being well-formed UTF-8. Returns true if successful, false otherwise.

_utf8_on(STRING)

[INTERNAL] Turn on the UTF-8 flag in STRING. The data in STRING is not checked for being well-formed UTF-8. Do not use unless you know that the STRING is well-formed UTF-8. Returns the previous state of the UTF-8 flag (so please don't test the return value as not success or failure), or undef if STRING is not a string.

_utf8_off(STRING)

[INTERNAL] Turn off the UTF-8 flag in STRING. Do not use frivolously. Returns the previous state of the UTF-8 flag (so please don't test the return value as not success or failure), or undef if STRING is not a string.

SEE ALSO

Encode::Encoding, Encode::Supported, Encode::PerlIO, encoding, perlebcdic, "open" in perlfunc, perlunicode, utf8, the Perl Unicode Mailing List <perl-unicode@perl.org>

MAINTAINER

This project was originated by Nick Ing-Simmons and later maintained by Dan Kogai <dankogai@dan.co.jp>. See AUTHORS for full list of people involved. For any questions, use <perl-unicode@perl.org> so others can share.

cpanm Encode

perl -MCPAN -e shell
install Encode