From Code to Community: Sponsoring The Perl and Raku Conference 2025 Learn more

EXODIST / Test2-Harness-0.001031 / lib / Test2 / Harness / Job / Runner / Open3.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
—
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129

              
package Test2::Harness::Job::Runner::Open3;
use strict;
use warnings;
our $VERSION = '0.001031';
use IPC::Open3 qw/open3/;
use Test2::Harness::Util qw/open_file write_file local_env/;
use Test2::Util qw/pkg_to_file/;
use Carp qw/cluck/;
use File::Spec();
sub viable { cluck __PACKAGE__ . " is deprecated"; 1 }
sub find_inc {
    my $class = shift;
    # Find out where Test2::Harness::Run::Worker came from, make sure that is in our workers @INC
    my $inc = $INC{"Test2/Harness/Job/Runner.pm"};
    $inc =~ s{/Test2/Harness/Job/Runner\.pm$}{}g;
    return File::Spec->rel2abs($inc);
}
sub command_file {
    my $class = shift;
    my ($test) = @_;
    return File::Spec->abs2rel($test->job->file);
}
sub command {
    my $class = shift;
    my ($test, $event_file) = @_;
    my $job = $test->job;
    my %seen;
    return (
        $^X,
        (map { "-I$_" } grep {!$seen{$_}++} @{$job->libs}, $class->find_inc, @INC),
        $ENV{HARNESS_PERL_SWITCHES} ? $ENV{HARNESS_PERL_SWITCHES} : (),
        @{$job->switches},
        (map {"-M$_"} @{$job->load_import || []}),
        (map {"-m$_"} @{$job->load || []}),
        $job->use_stream ? ("-MTest2::Formatter::Stream=file,$event_file") : (),
        $job->times ? ('-MTest2::Plugin::Times') : (),
        $class->command_file($test),
        @{$job->args},
    );
}
sub run {
    my $class = shift;
    my ($test) = @_;
    my $job = $test->job;
    my ($in_file, $out_file, $err_file, $event_file) = $test->output_filenames;
    my $out_fh = open_file($out_file, '>');
    my $err_fh = open_file($err_file, '>');
    write_file($in_file, $job->input);
    my $in_fh = open_file($in_file, '<');
    my $env = {
        %{$job->env_vars},
        $job->use_stream ? (T2_FORMATTER => 'Stream') : (),
    };
    my @cmd = $class->command($test, $event_file);
    my $pid;
    local_env $env => sub {
        $pid = open3(
            '<&' . fileno($in_fh), ">&" . fileno($out_fh), ">&" . fileno($err_fh),
            @cmd,
        );
    };
    return ($pid, undef);
}
1;
__END__
=pod
=encoding UTF-8
=head1 NAME
Test2::Harness::Job::Runner::Open3 - Logic for running a test in a new perl
process.
=head1 DESCRIPTION
=head1 SOURCE
The source code repository for Test2-Harness can be found at
F<http://github.com/Test-More/Test2-Harness/>.
=head1 MAINTAINERS
=over 4
=item Chad Granum E<lt>exodist@cpan.orgE<gt>
=back
=head1 AUTHORS
=over 4
=item Chad Granum E<lt>exodist@cpan.orgE<gt>
=back
=head1 COPYRIGHT
Copyright 2017 Chad Granum E<lt>exodist7@gmail.comE<gt>.
This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.
See F<http://dev.perl.org/licenses/>
=cut