NAME

Prima::Drawable - 2-D graphic interface

SYNOPSIS

   if ( $object-> isa('Prima::Drawable')) {
        $object-> begin_paint;
	$object-> color( cl::Black);
	$object-> line( 100, 100, 200, 200);
	$object-> ellipse( 100, 100, 200, 200);
        $object-> end_paint;
   }

DESCRIPTION

Prima::Drawable is a descendant of Prima::Component. It provides access to the system graphic context and canvas through its methods and properties. The Prima::Drawable descendants Prima::Widget, Prima::Image, Prima::DeviceBitmap and Prima::Printer are backed by system-dependent routines that allow drawing and painting on the system objects.

USAGE

Prima::Drawable, as well as its ancestors Prima::Component and Prima::Object, is never used directly, because Prima::Drawable class by itself provides only the interface. It provides a three-state object access - when drawing and painting is enabled, when these are disabled, and the information acquisition state. By default, the object is created in paint-disabled state. To switch to the enabled state, begin_paint() method is used. Once in the enabled state, the object drawing and painting methods apply to the system canvas. To return to the disabled state, end_paint() method is called. The information state can be managed by using begin_paint_info() and end_paint_info() methods pair. An object cannot be triggered from the information state to the enabled state ( and vice versa ) directly. These work differently with the graphic context and the canvas.

Graphic context and canvas

The graphic context is the set of variables, that control how exactly graphic primitives are rendered. The variable examples are color, font, line width, etc. Another term used here is canvas - the graphic area of a certain extent, connected to the Prima object, where the drawing and painting methods are used on.

In all three states a graphic context is allowed to be modified, but in different ways. In the disabled state a graphic context value is saved as a template; when an object enters the information or the enabled state, all values are preserved, but when the object is back to the disabled state, the graphic context is restored to the values last assigned before entering the enabled state. The code example below illustrates the idea:

$d = Prima::Drawable-> create;
$d-> lineWidth( 5);
$d-> begin_paint_info;
# lineWidth is 5 here
$d-> lineWidth( 1);
# lineWidth is 1
$d-> end_paint_info;
# lineWidth is 5 again

( Note: ::region, ::clipRect and ::translate properties are exceptions. They cannot be used in the disabled state; their values are neither recorded nor used as a template).

That is, in the disabled state any Drawable maintains only the graphic context values. To draw on a canvas, the object must enter the enabled state by calling begin_paint(). This function can be unsuccessful, because the object binds with system resources during this stage, and allocation of those may fail. Only after the enabled state is entered, the canvas is accessible:

$d = Prima::Image-> create( width => 100, height => 100);
if ( $d-> begin_paint) {
   $d-> color( cl::Black);
   $d-> bar( 0, 0, $d-> size);
   $d-> color( cl::White);
   $d-> fill_ellipse( $d-> width / 2, $d-> height / 2, 30, 30);
   $d-> end_paint;
} else {
   die "can't draw on image:$@";
}

Different objects are mapped to different types of canvases - Prima::Image canvas pertains its content after end_paint(), Prima::Widget maps it to some screen area, which content is of more transitory nature, etc.

The information state is as same as the enabled state, but the changes to the canvas are not visible. Its sole purpose is to read, not to write information. Because begin_paint() requires some amount of system resources, there is a chance that a resource request can fail, for any reason. The begin_paint_info() requires some resources as well, but usually much less, and therefore if only information is desired, it is usually faster and cheaper to obtain it inside the information state. A notable example is get_text_width() method, that returns the length of a text string in pixels. It works in both enabled and information states, but code

$d = Prima::Image-> create( width => 10000, height => 10000);
$d-> begin_paint;
$x = $d-> get_text_width('A');
$d-> end_paint;

is much more 'expensive' than

$d = Prima::Image-> create( width => 10000, height => 10000);
$d-> begin_paint_info;
$x = $d-> get_text_width('A');
$d-> end_paint_info;

for the obvious reasons.

It must be noted that some information methods like get_text_width() work even under the disabled state; the object is switched to the information state implicitly if it is necessary.

Color space

Graphic context and canvas operations rely completely on a system implementation. The internal canvas color representation is therefore system-specific, and usually could not be described in Prima definitions. Often the only information available about color space is its color depth.

Therefore all color manipulations, including dithering and antialiasing are subject to system implementation, and can not be controlled from perl code. When a property is set on the object in the disabled state, it is recorded verbatim; color properties are no exception. After the object switched to the enabled state, a color value is translated to the system color representation, which might be different from Prima's. For example, if the display color depth is 15 bits, 5 bits for every component, then the white color value 0xffffff is mapped to

11111000 11111000 11111000
--R----- --G----- --B-----

that equals to 0xf8f8f8, not 0xffffff ( See Prima::gp-problems for inevident graphic issues discussion ).

The Prima::Drawable color format is RRGGBB, with each component resolution of 8 bit, thus allowing 2^24 color combinations. If the device color space depth is different, the color is truncated or expanded automatically. In case the device color depth is insufficient, dithering algorithms may apply.

Note: not only color properties, but all graphic context properties allow all possible values in the disabled state, which are translated into system-allowed values when entering the enabled and the information states. This feature can be used to test if a graphic device is capable of performing certain operations ( for example, if it supports raster operations - the printers usually do not ). Example:

$d-> begin_paint;
$d-> rop( rop::Or);
if ( $d-> rop != rop::Or) { # this assertion is always false without
   ...                      # begin_paint/end_paint brackets
}
$d-> end_paint;

There are ( at least ) two color properties on each drawable - ::color and ::backColor. The values they operate are unsigned integers in the discussed above RRGGBB format, however, the toolkit defines some mnemonic color constants as well:

cl::Black
cl::Blue
cl::Green
cl::Cyan
cl::Red
cl::Magenta
cl::Brown
cl::LightGray
cl::DarkGray
cl::LightBlue
cl::LightGreen
cl::LightCyan
cl::LightRed
cl::LightMagenta
cl::Yellow
cl::White
cl::Gray

As stated before, it is not unlikely that if a device color depth is insufficient, where the primitives could be drawn with dithered or incorrect colors. This usually happens on paletted displays, with 256 or less colors.

There exists two methods that facilitate the correct color representation. The first way is to get as much information as possible about the device. The methods get_nearest_color() and get_physical_palette() provide possibility to avoid mixed colors drawing by obtaining indirect information about solid colors, supported by a device. Another method is to use ::palette property. It works by inserting the colors into the system palette, so if an application knows the colors it needs beforehand, it can employ this method - however this might result in system palette flash when a window focus toggles.

Both of these methods are applicable both with drawing routines and image output. An application that desires to display an image with least distortion is advised to export its palette to an output device, because images usually are not subject to automatic dithering algorithms. Prima::ImageViewer module employs this scheme.

Antialiasing and alpha

If the system has capability for antialiased drawing and alpha rendering, Prima can use it. The render mode can be turned on by calling

$drawable->antialias(1)

which turns on the following effects:

All primitives except images, pixel, and bar_alpha are plotted with antialiased edges (text is always antialiased when possible). Arcs, lines, paths, all of them manifest adjacent pixels being rendered with half-tones.
Graphic coordinates are then used as floating point numbers, not integers. That means that f ex a call
```
$drawable->rectangle(5.3, 5.3, 10, 10)
```
that had its coordinates automatically rounded to (5,5,10,10), now will render the primitive with subpixel precision, where its two edges will be divided between pixels 5 and 6, by using half-tones.

Another note on the rounding off coordinates: historically almost all Prima pixel coordinates were integers, and implicit rounding of the passed numbers were done using the int function, i e int(0.7)=0 and int(-0.7)=0. This was later changed, breaking some backward compatibility, and now the rounding function is a more robust R = floor(x + 0.5), where R(0.7) = 1 and R(-0.7) = -1.

For the cases where system does not support antialiasing, Prima provides Prima::Drawable::Antialias emulation class, available through the new_aa_surface call. Internal image painting routines uses this facility as well.

To see if alpha and antialiasing is supported on the system, check sv::Antialias value. To see if a particular drawable supports alpha layering, check can_draw_alpha method.

Note that in the render mode, all painting operations treat alpha channel differently, which can have a dramatic difference on layered surfaces. In the normal mode, the alpha channel is completely ignored, and using normal mode paints on a layered widget always produces a translucent window, because the alpha value will always be 0 and color bits are assumed to be already premultiplied. In the render mode, alpha channel is addressed by alpha property when drawing primitives, or in mask property when drawing icons (again, drawing images and non-layered bitmaps assumes alpha = 0). The same is valid for fill pattern images and fill pattern icons.

Monochrome bitmaps

Prima has special rules when drawing a monochrome Prima::DeviceBitmap. Such objects don't possess an inherent color palette, and by definition are bitmaps with only two pixel values present, 0s and 1s. When a monochrome bitmap is drawn, 0s are painted using the color value of the target canvas color property, and 1s using the backColor value.

That means that the following code

$bitmap-> color(0);
$bitmap-> line(0,0,100,100);
$target-> color(cl::Green);
$target-> put_image(0,0,$bitmap);

produces a green line on $target.

When using monochrome bitmaps for logical operations, note that the target colors should not be explicit 0 and 0xffffff, nor cl::Black and cl::White, but cl::Clear and cl::Set instead. The reason is that on paletted displays, system palette may not necessarily contain the white color under palette index (2^ScreenDepth-1). cl::Set thus signals that the value should be "all ones", no matter what color it represents, because it will be used for logical operations.

Fonts

Prima maintains its own font naming convention, that usually does not conform to the system's. Since Prima's goal is interoperability, it might be so that some system fonts would not be accessible from within the toolkit.

Prima::Drawable provides property ::font, that accepts/returns a hash, that represents the state of a font in the system graphic context. The font hash keys that are acceptable on set-call are:

name

The font name string. If there is no such font, a default font name is used. To select default font, a 'Default' string can be passed with the same result ( unless the system has a font named 'Default', of course).

height

An integer value from 1 to MAX_INT. Specifies the desired extent of a font glyph between descent and ascent lines in pixels.

size

An integer value from 1 to MAX_INT. Specifies the desired extent of a font glyph between descent and internal leading lines in points. The relation between size and height is

          height - internal_leading
size =  --------------------------- * 72.27
               resolution

That differs from some other system representations: Win32, for example, rounds 72.27 constant to 72.

width

A integer value from 0 to MAX_INT. If greater than 0, specifies the desired extent of a font glyph width in pixels. If 0, sets the default ( designed ) width corresponding to the font size or height.

style

A combination of fs:: ( font style ) constants. The constants

fs::Normal
fs::Bold
fs::Thin
fs::Italic
fs::Underlined
fs::StruckOut
fs::Outline

can be OR-ed together to express the font style. fs::Normal equals to 0 and usually never used. If some styles are not supported by a system-dependent font subsystem, they are ignored.

pitch

One of three constants:

fp::Default
fp::Fixed
fp::Variable

fp::Default specifies no interest about font pitch selection. fp::Fixed is set when a monospaced (all glyphs are of same width) font is desired. fp::Variable pitch specifies a font with different glyph widths. This key is of the highest priority; all other keys may be altered for the consistency of the pitch key.

vector

One of three constants:

fv::Default
fv::Bitmap
fv::Outline

fv::Default specifies no interest about font type selection, fv::Bitmap sets priority for the bitmap fonts, fv::Outline for the vector fonts.

Additionally, font entries returned from fonts method may set vector to fv::ScalableBitmap, to distinguish a bitmap font face that comes with predefined bitmap sets from a scalable font.

direction

A counter-clockwise rotation angle - 0 is default, 90 is pi/2, 180 is pi, etc. If a font could not be rotated, it is usually substituted with the one that can.

encoding

A string value, one of the strings returned by Prima::Application::font_encodings. Selects desired font encoding; if empty, picks the first matched encoding, preferably the locale set up by the user.

The encodings provided by different systems are different; in addition, the only encodings are recognizable by the system, that are represented by at least one font in the system.

Unix systems and the toolkit PostScript interface usually provide the following encodings:

iso8859-1
iso8859-2
... other iso8859 ...
fontspecific

Win32 returns the literal strings like

Western
Baltic
Cyrillic
Hebrew
Symbol

A hash that ::font returns, is a tied hash, whose keys are also available as separate properties. For example,

$x = $d-> font-> {style};

is equivalent to

$x = $d-> font-> style;

While the latter gives nothing but the arguable coding convenience, its usage in set-call is much more usable:

$d-> font-> style( fs::Bold);

instead of

my %temp = %{$d-> font};
$temp{ style} = fs::Bold;
$d-> font( \%temp);

The properties of a font tied hash are also accessible through set() call, like in Prima::Object:

$d-> font-> style( fs::Bold);
$d-> font-> width( 10);

is an equivalent to

$d-> font-> set(
   style => fs::Bold,
   width => 10,
);

When get-called, ::font property returns a hash where more entries than the described above can be found. These keys are read-only, their values are ignored if passed to ::font in a set-call.

In order to query the full list of fonts available to a graphic device, the ::fonts method is used. This method is not present in Prima::Drawable namespace; it can be found in two built-in class instances, Prima::Application and Prima::Printer.

Prima::Application::fonts returns metrics for the fonts available to the screen device, while Prima::Printer::fonts ( or its substitute Prima::PS::Printer ) returns fonts for the printing device. The result of this method is an array of font metrics, fully analogous to these returned by Prima::Drawable::font method.

family

A string with font family name. The family is a secondary string key, used for distinguishing between fonts with same name but of different vendors ( for example, Adobe Courier and Microsoft Courier).

ascent

Number of pixels between a glyph baseline and descent line.

descent

Number of pixels between a glyph baseline and descent line.

internalLeading

Number of pixels between ascent and internal leading lines. Negative if the ascent line is below the internal leading line.

externalLeading

Number of pixels between ascent and external leading lines. Negative if the ascent line is above the external leading line.

Horizontal font measurements

weight

Font designed weight. Can be one of

fw::UltraLight
fw::ExtraLight
fw::Light
fw::SemiLight
fw::Medium
fw::SemiBold
fw::Bold
fw::ExtraBold
fw::UltraBold

constants.

maximalWidth

Maximal extent of a glyph in pixels. Equals to width in monospaced fonts.

xDeviceRes

Designed horizontal font resolution in dpi.

yDeviceRes

Designed vertical font resolution in dpi.

firstChar

Index of the first glyph present in a font.

lastChar

Index of the last glyph present in a font.

breakChar

Index of the default character used to divide words. In a typical western language font it is 32, ASCII space character.

defaultChar

Index of a glyph that is drawn instead of nonexistent glyph if its index is passed to the text drawing routines.

Font ABC metrics

Besides these characteristics, every font glyph has an ABC-metric, the three integer values that describe horizontal extents of a glyph's black part relative to the glyph extent:

A and C are negative, if a glyphs 'hangs' over it neighbors, as shown in picture on the left. A and C values are positive, if a glyph contains empty space in front or behind the neighbor glyphs, like in picture on the right. As can be seen, B is the width of a glyph's black part.

ABC metrics returned by the get_font_abc() method.

The corresponding vertical metrics, called in Prima DEF metrics, are returned by the get_font_def() method.

Raster operations

A drawable has two raster operation properties: ::rop and ::rop2. These define how the graphic primitives are plotted. ::rop deals with the foreground color drawing, and ::rop2 with the background.

Universal ROPs

The toolkit defines the following operations:

Usually, however, graphic devices support only a small part of the above set, limiting ::rop to the most important operations: Copy, And, Or, Xor, NoOp. ::rop2 is usually even more restricted, supports only Copy and NoOp.

The raster operations apply to all graphic primitives except SetPixel.

Note for layering: using layered images and device bitmaps with put_image and stretch_image can only use rop::SrcCopy and rop::Blend raster operations on OS-provided surfaces. See more on rop::Blend below.

Also, rop::AlphaCopy operation is available for accessing alpha bits only. When used, the source image is treated as alpha mask, and therefore it has to be grayscale. It can be used to apply the alpha bits independently, without need to construct an Icon object.

rop::Blend

rop::Blend is same as rop::SrcOver except the source pixels are assumed to be already premultiplied with the source alpha. This is the default ROP when drawing with 8-bit icon masks or on layered surfaces, and it reflects the expectation of the OS that images come premultiplied.

This is the only blending operator supported on the widgets and bitmaps, and it is advised to premultiply image pixels prior to drawing images using it with calls to Image.premultiply_alpha. Image drawing supports this operator in case these premultiplied images are to be used not only on native surfaces but also on Prima images.

Additional ROPs

Prima implements extra features for compositing on images outside the begin_paint/end_paint brackets. It supports the following 12+1 Porter-Duff operators and some selected Photoshop blend operators:

Transparency control

There is defined a set of constants to apply a constant source and destination alpha to when there is no alpha channel available:

rop::SrcAlpha
rop::SrcAlphaShift
rop::DstAlpha
rop::DstAlphaShift

Combine the rop constant using this formula:

$rop = rop::XXX |
   rop::SrcAlpha | ( $src_alpha << rop::SrcAlphaShift ) |
   rop::DstAlpha | ( $dst_alpha << rop::DstAlphaShift )

or by calling rop::alpha($rop, [ $src_alpha, [ $dst_alpha ]]) that does the same.

Also, the function rop::blend($alpha) creates a rop constant for simple blending of two images by the following formula:

$dst = ( $src * $alpha + $dst * ( 255 - $alpha ) ) / 255

rop::alpha also can be used for drawing on images outside begin_paint/end_paint with all Porter-Duff and Photoshop raster operators:

$image->rop( rop::alpha( rop::SrcOver, 128 ));
$image->ellipse( 5, 5, 5, 5 );

Note that when the raster operation is set to rop::SrcOver, the fully identical effect can be achieved by

$image->alpha(128);
$image->ellipse( 5, 5, 5, 5 );

as well.

When used with icons, their source and/or destination alpha channels are additionally multiplied with these values.

rop::ConstantColor

This bit is used when the alpha is defined but the main bits aren't. In this case, the main bits are filled from the destination's image color, and the source image treated as the source alpha channel. The following code applies a solid green shade with a mask loaded from file.

$src->load('8-bit gray mask.png');
$dst->color(cl::LightGreen);
$dst->put_image( 0,0,$src,rop::SrcOver | rop::ConstantColor);

Coordinates

The Prima toolkit employs the XY grid, where X ascends rightwards and Y ascends upwards. There, the (0,0) location is the bottom-left pixel of a canvas.

All graphic primitives use inclusive-inclusive boundaries. For example,

$d-> bar( 0, 0, 1, 1);

plots a bar that covers 4 pixels: (0,0), (0,1), (1,0) and (1,1).

The coordinate origin can be shifted using ::matrix property, that translates the (0,0) point to the given offset. Calls to ::matrix, ::clipRect and ::region always use the 'physical' (0,0) point, whereas the plotting methods use the transformation result, the 'logical' (0,0) point.

As noted before, these three properties cannot be used in when an object is in the disabled state.

Matrix

At the very bottom Prima::Drawable accepts matrix scalars in form of 6-item arrays, that constitute the following 2-D transformation matrix

A B DX
C D DY
0 0 1

where the coordinate transformation follows this formula:

x' = A x + B x + DX
y' = C y + D y + DY

. There are two accessors, get_matrix and set_matrix that return a copy, or copy a new matrix, correspondintly, from and to the drawable object.

The 6-item array that get_matrix returns is also a blessed object or type Prima::matrix ( see "Prima::matrix" in Prima::types ) that is a separate copy of the object matrix. Prima::matrix objects feature a set of oprations such as rotate and translate that transform the matrix further. In order to apply this matrix, one calls $drawable->set_matrix($matrix) or $matrix->apply($drawable).

There is also a property matrix, that is not really orthogonal to the get_matrix/ set_matrix method pair, as matrix returns a Prima::Matrix object, that, contrary to a Prima::matrix object returned by get_matrix, is a direct accessor to the drawable's matrix:

my $m = $self->get_matrix;
$m->translate(1,2);
$self->set_matrix($m); # or $self->matrix($m);

is the same as

$self->matrix->translate(1,2);

and does not need an explicit call to set_matrix or apply.

This class has all the methods the Prima::matrix has. See more in "Prima::Matrix" in Prima::types.

Custom line end styles

Prima uses its own plotting mechanism in Prima::Drawable::Path to produce all primitive shapes, including lines. The way lines are plotted is governed by properties lineEnd, lineJoin, linePattern, and miterLimit. All of these properties are described below, however lineEnd provides rich capabilities to generate custom line ends, and this is what described in this section.

le:: namespace

There are 3 predefined le:: integer constants

that are hardcoded in Prima, that are accepted by the lineEnd property. These constants are somewhat limited in the way one can operate them, for the sake of efficiency.

It is also possible to supply an array descriptor that defines a set of primitives that plots a line cap, automatically transformed with respect to the current line tangent and width. Details of the descriptor syntax itself are given in the next section, while here the set of non-hardcoded line end functions is listed, that is also suitable for use in the lineEnd property.

le::Arrow
le::Cusp
le::InvCusp
le::Knob
le::Rect
le::RoundRect
le::Spearhead
le::Tail

These descriptors could be arbitrarily transformed (f ex scaled):

# all three lines produce the same effect
$x->lineEnd( le::scale( Arrow => 1.5 ) );
$x->lineEnd( le::transform( le::Arrow, [1.5,0,0,1.5,0,0] ) );
$x->lineEnd( le::transform( le::Arrow, Prima::matrix->new->scale(1.5) ) );

Line ends with x 1.5 scaling

lineEnd accessors

The lineEnd property can accept up to 4 line end definitions, depending on syntax. When Prima plots lines, depending on the location of a line end, one of these 4 definitions is selected. Each definition also has its own property - see "lineHead", "lineTail", "arrowHead", and "arrowTail", or a index-based accessor lineEndIndex:

Line end syntax

The syntax for custom line end style is:

syntax  ::= array of pairs
pair    ::= command, array of points
command ::= line or conic or cubic
points  ::= set of x,y coordinate pairs (vertices)

where individual commands accept arbitrary number of vertices, but no less than 1 for line, 2 for conic, and 3 for cubic.

The commands are executed sequentially on a coordinate grid where line width is assumed to be 1, the plotting starts from point at (1,0), and ends at (-1,0).

For example, this is the definition of le::Arrow:

     [
	conic => [1,0,2.5,0,2.5,-0.5],
	line  => [0,2.5],
	conic => [-2.5,-0.5,-2.5,0,-1,0]
     ]

API

Graphic context properties

alpha INTEGER

Sets alpha component of the brush, where 0 is fully transparent and 255 is fully opaque.

Note that premultiplication of color and backColor is not necessary as it is done internally.

Default: 255

antialias BOOLEAN

Turns on and off antialiased drawing on all primitives, excluding image, pixel, and bar_alpha calls.

It will not be possible to turn the property on if the system does not support it. Also, monochrome images won't support it as well.

See "Antialiasing and alpha".

arrowHead

Defines the style to paint line heads on starting or ending points used to define a line or polygon. Is never used on closed shapes. If undef, the heads are painted with the same style as lineHead

Default value: le::Round. Cannot be undef.

arrowTail

Defines the style to paint line tails on starting or ending points used to define a line or polygon. Is never used on closed shapes. If undef, the heads are painted with the same style as lineTail; if it is also undef, then the style of lineHead is used.

Default value: undef

backColor COLOR

Sets background color to the graphic context. All drawing routines that use non-solid or transparent fill or line patterns use this property value.

color COLOR

Sets foreground color to the graphic context. All drawing routines use this property value.

clipRect X1, Y1, X2, Y2

Selects the clipping rectangle corresponding to the physical canvas origin. On get-call, returns the extent of the clipping area, if it is not rectangular, or the clipping rectangle otherwise. The code

$d-> clipRect( 1, 1, 2, 2);
$d-> bar( 0, 0, 1, 1);

thus affects only one pixel at (1,1).

Set-call discards the previous ::region value.

Note: ::clipRect can not be used while the object is in the paint-disabled state, its context is neither recorded nor used as a template ( see "Graphic context and canvas") -- except on images.

fillMode INTEGER

Affects filling style of complex polygonal shapes filled by fillpoly. If fm::Winding, the filled shape contains no holes; if fm::Alternate, holes are present where the shape edges cross.

fm::Overlay flag can be combined with these to counter an intrinsic defect of filled shaped both in Win32 and X11 that don't exactly follow polygon vertices. When supplied, it overlays a polygon over the filled shape, so that the latter falls exactly in the boundaries defined by vertices. This is desirable when one wants the shape to be defined exactly by polygon vertices, but is not desirable when a shape has holes in it and is connected in a way that the polygon overlay may leave visible connection edges over them.

Default value: fm::Winding|fm::Overlay

fillPattern ( [ @PATTERN ] ) or ( fp::XXX ) or IMAGE

Selects 8x8 fill pattern that affects primitives that plot filled shapes: bar(), fill_chord(), fill_ellipse(), fillpoly(), fill_sector(), floodfill().

Accepts either a fp:: constant or a reference to an array of 8 integers, or an image reference. In all cases, except where the image is colored, treats 0s in the pattern as the currently selected backColor, and 1s as color. When rop2 is set to rop::NoOper, treats 0s as fully transparent pixels. Additionally, in the render mode respects the alpha property.

Note: Drawing over monochome bitmap or image will not respect its rop on Win32.

Depending on the parameters, treats the input as follows:

fp:: constant

There are some predefined patterns, that can be referred via fp:: constants:

( the actual patterns are hardcoded in api/api.c ) The default pattern is fp::Solid.

On a get-call, does not return the fp:: value but the corresponding array (see below). If a constant value is needed to be recovered, use fp::builtin function that would return the constant from the array. There is also two shortcut functions, fp::is_solid and fp::is_empty that check if the fill pattern is all-ones or all-zeros, correspondingly.

Array

Wants an 8-item array where each item is a byte value, representing 8 bits of each line in a pattern. The first integer is the topmost pattern line, and the bit 0x80 is the leftmost pixel in the line.

An example below shows encoding of fp::Parquet pattern:

# 76543210
  84218421  Hex

0  $ $   $  51
1   $   $   22
2    $ $ $  15
3 $   $     88
4  $   $ $  45
5   $   $   22
6  $ $ $    54
7 $   $     88

$d-> fillPattern([ 0x51, 0x22, 0x15, 0x88, 0x45, 0x22, 0x54, 0x88 ]);

Monochrome image

Like the array above, wants an image consisting of 0s and 1s where these would represent canvas' backColor and color, correspondinly, when rendered. In the same fashion, when rop2 is set to rop::NoOper, zeros will be treated as transparent pixels.

Color image

Ignores color, and backColor, and rop2. Just uses the tiles and the current alpha value.

Icon

Ignores color, backColor, and rop2. Uses the alpha pixel values from the icon's mask and the current alpha value.

fillPatternOffset X, Y

Origin coordinates for the fillPattern. Image patterns origin (0,0) is system-dependent.

font \%FONT

Manages font context. FONT hash acceptable values are name, height, size, width, style and pitch.

Synopsis:

$d-> font-> size( 10);
$d-> font-> name( 'Courier');
$d-> font-> set(
  style => $x-> font-> style | fs::Bold,
  width => 22
);

See "Fonts" for the detailed descriptions.

Applies to text_out(), get_text_width(), get_text_box(), get_font_abc(), get_font_def(), render_glyph().

font_mapper

Returns a font mapper object that provides interface to fonts collection used for substitution in polyfont shaping (see "text_shape"). The fonts can be accessed there either by their font hash (name and style only, currently), or the font's corresponding index.

There are two font lists used in the substitution mechanism, passive and active. The passive font list is initiated during the toolkit start and is never changed. Each font there is addressed by an index. When the actual search for a glyph is initiated, these fonts are queried in the loop and are checked if they contain the required glyphs. These queries are also cached, so that next time lookups run much quicker. That way, an active font list is built, and next substitutions use it before trying to look into the passive list. Since the ordering of fonts is system based, and is rather random, some fonts may not be a good or aesthetic substitution. Therefore the mapper can assist in adding or removing particular fonts to the active list, potentially allowing an application to store and load user-driven selection of substitution fonts.

The following methods are available on the font mapper object:

activate %FONT: Adds the FONT into the active substitution list if the font is not disabled
get INDEX: Returns the font hash registered under INDEX
count: Returns number of all fonts in the collection
index: Returns what index is assigned to the currently used font, if any
passivate %FONT: Remove the font from the active substitution list
is_active %FONT: Returns whether the font is in the active substitution list or not
enable %FONT: Enables the font entry, the font will be considered for the polyfont lookup
disable %FONT: Disables the font entry, the font will not be considered for the polyfont lookup
is_enabled %FONT: Returns whether the font is enabled or not

lineHead

Defines the style to paint line heads in patterned lines only, on line segments that do not lie on line starting or ending points used to define a line or polygon.

Default value: undef

lineEnd VALUE

Selects a line ending cap for plotting primitives. VALUE can be one of

constants, undef, a custom line end description, or an array of four where each entry is one of the values above.

The undef value is only accepted in the array syntax, and not for the index 0 ("lineHead"). The other indexes behave differently if are set to undef - see more in "lineTail", "arrowHead", "arrowTail", "lineEndIndex".

le::Round is the default value.

Other properties

height HEIGHT: Selects the height of a canvas.
size WIDTH, HEIGHT: Selects the extent of a canvas.
width WIDTH: Selects the width of a canvas.

Graphic primitives methods

arc X, Y, DIAMETER_X, DIAMETER_Y, START_ANGLE, END_ANGLE

Plots an arc with center in X, Y and DIAMETER_X and DIAMETER_Y axes from START_ANGLE to END_ANGLE.

Context used: color, backColor, lineEnd, linePattern, lineWidth, miterLimit, rop, rop2

bar X1, Y1, X2, Y2

Draws a filled rectangle within (X1,Y1) - (X2,Y2) extents.

Context used: color, backColor, fillPattern, fillPatternOffset, rop, rop2

bar_alpha ALPHA <X1, Y1, X2, Y2>

Fills rectangle in the alpha channel, filled with ALPHA value (0-255) within (X1,Y1) - (X2,Y2) extents. Can be called without parameters, in this case fills all canvas area.

Has only effect on layered surfaces.

bars @RECTS

Draws a set of filled rectangles. RECTS is an array of integer quartets in format (X1,Y1,X2,Y2).

Context used: color, backColor, fillPattern, fillPatternOffset, rop, rop2

chord X, Y, DIAMETER_X, DIAMETER_Y, START_ANGLE, END_ANGLE

Plots an arc with center in X, Y and DIAMETER_X and DIAMETER_Y axes from START_ANGLE to END_ANGLE and connects its ends with the straight line.

Context used: color, backColor, lineEnd, linePattern, lineWidth, miterLimit, rop, rop2

clear <X1, Y1, X2, Y2>

Draws rectangle filled with pure background color within (X1,Y1) - (X2,Y2) extents. Can be called without parameters, in this case fills all canvas area.

Context used: backColor, rop2

draw_text CANVAS, TEXT, X1, Y1, X2, Y2, [ FLAGS = dt::Default, TAB_INDENT = 1 ]

Draws several lines of text one under another with respect to align and break rules, specified in FLAGS and TAB_INDENT tab character expansion.

draw_text is a convenience wrapper around text_wrap for drawing the wrapped text, and also provides the tilde ( ~ )- character underlining support.

The FLAGS is a combination of the following constants:

dt::Left                  - text is aligned to the left boundary
dt::Right                 - text is aligned to the right boundary
dt::Center                - text is aligned horizontally in center
dt::Top                   - text is aligned to the upper boundary
dt::Bottom                - text is aligned to the lower boundary
dt::VCenter               - text is aligned vertically in center
dt::DrawMnemonic          - tilde-escapement and underlining is used
dt::DrawSingleChar        - sets tw::BreakSingle option to
                            Prima::Drawable::text_wrap call
dt::NewLineBreak          - sets tw::NewLineBreak option to
                            Prima::Drawable::text_wrap call
dt::SpaceBreak            - sets tw::SpaceBreak option to
                            Prima::Drawable::text_wrap call
dt::WordBreak             - sets tw::WordBreak option to
                            Prima::Drawable::text_wrap call
dt::ExpandTabs            - performs tab character ( \t ) expansion
dt::DrawPartial           - draws the last line, if it is visible partially
dt::UseExternalLeading    - text lines positioned vertically with respect to
                            the font external leading
dt::UseClip               - assign ::clipRect property to the boundary rectangle
dt::QueryLinesDrawn       - calculates and returns number of lines drawn
                            ( contrary to dt::QueryHeight )
dt::QueryHeight           - if set, calculates and returns vertical extension
                            of the lines drawn
dt::NoWordWrap            - performs no word wrapping by the width of the boundaries
dt::WordWrap              - performs word wrapping by the width of the boundaries
dt::Default               - dt::NewLineBreak|dt::WordBreak|dt::ExpandTabs|
                            dt::UseExternalLeading

Context used: color, backColor, font, rop, textOpaque, textOutBaseline

ellipse X, Y, DIAMETER_X, DIAMETER_Y

Plots an ellipse with center in X, Y and DIAMETER_X and DIAMETER_Y axes.

Context used: color, backColor, linePattern, lineWidth, rop, rop2

fill_chord X, Y, DIAMETER_X, DIAMETER_Y, START_ANGLE, END_ANGLE

Fills a chord outline with center in X, Y and DIAMETER_X and DIAMETER_Y axes from START_ANGLE to END_ANGLE (see chord()).

Context used: color, backColor, fillPattern, fillPatternOffset, rop, rop2

fill_ellipse X, Y, DIAMETER_X, DIAMETER_Y

Fills an elliptical outline with center in X, Y and DIAMETER_X and DIAMETER_Y axes.

Context used: color, backColor, fillPattern, fillPatternOffset, rop, rop2

fillpoly \@POLYGON

Fills a polygonal area defined by POLYGON set of points. POLYGON must present an array of integer pair in (X,Y) format. Example:

$d-> fillpoly([ 0, 0, 15, 20, 30, 0]); # triangle

Context used: color, backColor, fillPattern, fillPatternOffset, rop, rop2, fillMode

Returns success flag; if failed, $@ contains the error.

Methods

begin_paint

Enters the enabled ( active paint ) state, returns success flag; if failed, $@ contains the error. Once the object is in enabled state, painting and drawing methods can perform write operations on a canvas.

See also: end_paint, begin_paint_info, "Graphic context and canvas"

begin_paint_info

Enters the information state, returns success flag; if failed, $@ contains the error. The object information state is same as enabled state ( see begin_paint), except painting and drawing methods do not change the object canvas.

See also: end_paint_info, begin_paint, "Graphic context and canvas"

can_draw_alpha

Returns whether using alpha bits operation on the drawable will have any effect or not. Note that the drawable may not necessarily have an alpha channel, for example a normal RGB image is capable to be painted on with alpha while not having any alpha on its own. On unix, all non-1 bit drawables return true if Prima was compiled with XRender support and if that extension is present on the X server. On windows, all non-1 bit drawables return true unconditionally.

AUTHOR

Dmitry Karasik, <dmitry@karasik.eu.org>.

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	go to github issues (only if github is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

	Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)

NAME

SYNOPSIS

DESCRIPTION

USAGE

Graphic context and canvas

Color space

Antialiasing and alpha

Monochrome bitmaps

Fonts

Font ABC metrics

Raster operations

Universal ROPs

rop::Blend

Additional ROPs

Coordinates

Matrix

Custom line end styles

API

Graphic context properties

Other properties

Graphic primitives methods

Methods

AUTHOR

SEE ALSO

Module Install Instructions