/ 
Log-Report-0.01
River stage two • 36 direct dependents • 86 total dependents
/ Log::Report::Message

NAME

Log::Report::Message - a piece of text to be translated

SYNOPSIS

Used internally by Log::Report

DESCRIPTION

Any used of a translation function, like Log::Report::__() or Log::Report::__x() will result in this object. It will capture some environmental information, and delay the translation until it is needed.

Creating an object first, and translating it later, is slower than translating it immediately. However, on the location where the message is produced, we do not yet know to what language to translate: that depends on the front-end, the log dispatcher.

See "DETAILS" section below, for an in-depth description.

METHODS

Constructors

$obj->clone(OPTIONS, VARIABLES)

    Returns a new object which copies info from original, and updates it with the specified OPTIONS and VARIABLES. The advantage is that the cached translations are shared between the objects.

    Example: use of clone()

    my $s = __x "found {nr} files", nr => 5;
my $t = $s->clone(nr => 3);
my $t = $s->(nr => 3);      # equivalent
print $s;     # found 5 files
print $t;     # found 3 files

$obj->concat(STRING|OBJECT, [REVERSED])

    This method implements the overloading of concatenation, which is needed to delay translations even longer. When REVERSED is true, the STRING or OBJECT (other Log::Report::Message) needs to prepended, otherwise appended.

    Example: of concatenation

    print __"Hello" . ' ' . __"World!";
print __("Hello")->concat(' ')->concat(__"World!")->concat("\n");

Log::Report::Message->new(OPTIONS, VARIABLES)

    Option   --Default
_category  undef
_count     undef
_domain    from use
_expand    false
_msgid     undef
_plural    undef

    . _category => INTEGER

    . _count => INTEGER

      When defined, then _plural need to be defined as well.

    . _domain => STRING

      The textdomain in which this msgid is defined.

    . _expand => BOOLEAN

      Indicates whether variables are filled-in.

    . _msgid => MSGID

      The message label, which refers to some translation information. Usually a string which is close the English version of the error message. This will also be used if there is no translation possible

    . _plural => MSGID

      Can be specified when a _count is specified. This plural form of the message is used to simplify translation, and as fallback when no translations are possible: therefore, this can best resemble an English message.

$obj->toString([LOCALE])

    Translate a message. If not specified, the default locale is used.

DETAILS

OPTIONS and VARIABLES

The Log::Report functions which define translation request can all have OPTIONS. Some can have VARIABLES to be interpolated in the string as well. To distinguish between the OPTIONS and VARIABLES (both a list of key-value pairs), the keys of the OPTIONS start with an underscore _. As result of this, please avoid the use of keys which start with an underscore in variable names. On the other hand, you are allowed to interpolate OPTION values in your strings.

Interpolating

With the __x() or __nx(), interpolation will take place on the translated MSGID string. The translation can contain the VARIABLE and OPTION names inbetween curly brackets. Text between curly brackets which is not a known parameter will be left untouched.

Next to the name, you can specify a format code. With gettext(), you often see this:

printf gettext("approx pi: %.6f\n"), PI;

Locale::TextDomain has two ways.

printf __"approx pi: %.6f\n", PI;
print __x"approx pi: {approx}\n", approx => sprintf("%.6f", PI);

The first does not respect the wish to be able to reorder the arguments during translation. The second version is quite long. With Log::Report, above syntaxes do work, but you can also do

print __x"approx pi: {pi%.6f}\n", pi => PI;

So: the interpolation syntax is { name [format] } . Other examples:

print __x "{perms} {links%2d} {user%-8s} {size%10d} {fn}\n"
        , perms => '-rw-r--r--', links => 1, user => 'me'
        , size => '12345', fn => $filename;

An additional advantage is the fact that not all languages produce comparible length strings. Now, the translators can take care that the layout of tables is optimal.

Interpolation of OPTIONS

You are permitted the interpolate OPTION values in your string. This may simplify your coding. The useful names are:

_msgid

The MSGID as provided with Log::Report::__() and Log::Report::__x()

_msgid, _plural, _count

The single MSGID and PLURAL MSGIDs, respectively the COUNT as used with Log::Report::__n() and Log::Report::__nx()

_textdomain

The label of the textdomain in which the translation takes place.

Example: using the _count

With Locale::TextDomain, you have to do

use Locale::TextDomain;
print __nx ( "One file has been deleted.\n"
           , "{num} files have been deleted.\n"
           , $num_files
           , num => $num_files
           );

With Log::Report, you can do

use Log::Report;
print __nx ( "One file has been deleted.\n"
           , "{_count} files have been deleted.\n"
           , $num_files
           );

Of course, you need to be aware that the name used to reference the counter is pixed to _count. The first example works as well, but is more verbose.

Interpolation of VARIABLES

There is no way of checking beforehand whether you have provided all required values, to be interpolated in the translated string. A translation could be specified like this:

my @files = @ARGV;
local $"  = ', ';
my $s = __nx "One file specified ({files})"
           , "{_count} files specified ({files})"
           , scalar @files     # actually, 'scalar' is not needed
           , files => \@files;

For interpolating, the following rules apply:

.

Simple scalar values are interpolated "as is"

.

References to SCALARs will collect the value on the moment that the output is made. The Log::Report::Message object which is created with the __xn can be seen as a closure. The translation can be reused. See example below.

.

Code references can be used to create the data "under fly". The Log::Report::Message object which is being handled is passed as only argument. This is a hash in which all OPTIONS and VARIABLES can be found.

.

When the value is an ARRAY, all members will be interpolated with $" inbetween the elements.

Example: reducing the number of translations

This way of translating is somewhat expensive, because an object to handle the __x() is created each time.

for my $i (1..100_000)
{   print __x "Hello World {i}\n", $i;
}

The suggestion that Locale::TextDomain makes to improve performance, is to get the translation outside the loop, which only works without interpolation:

use Locale::TextDomain;
my $i = 42;
my $s = __x("Hello World {i}\n", i => $i);
foreach $i (1..100_000)
{   print $s;
}

Oops, not what you mean. With Log::Report, you can do

use Log::Report;
my $i;
my $s = __x("Hello World {i}", i => \$i);
foreach $i (1..100_000)
{   print $s;
}

Mind you not to write: for my $i in this case!!!! You can also write an incomplete translation:

use Log::Report;
my $s = __x "Hello World {i}";
foreach my $i (1..100_000)
{   print $s->(i => $i);
}

In either case, the translation will be looked-up only once.

SEE ALSO

This module is part of Log-Report distribution version 0.01, built on May 25, 2007. Website: http://perl.overmeer.net/logreport/

LICENSE

Copyrights 2007 by Mark Overmeer. For other contributors see ChangeLog.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself. See http://www.perl.com/perl/misc/Artistic.html