Dave Cross: Still Munging Data With Perl: Online event - Mar 17 Learn more

MLAWREN / App-bif-0.1.4 / lib / App / bif / check.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
—
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153

              
package App::bif::check;
use strict;
use warnings;
use feature 'say';
use lib 'lib';
use parent 'App::bif';
use Bif::DB::Plugin::Changes;
use DBIx::ThinSQL qw/sq qv/;
use Digest::SHA qw/sha1_hex/;
use OptArgs;
use Text::Diff qw/diff/;
use YAML::Tiny qw/Dump/;
our $VERSION = '0.1.4';
# TODO Work out how to yamlcheck utf8 chars
sub run {
    my $self = shift;
    my $opts = $self->opts;
    my $db   = $self->db;
    my $sth = $db->xprepare_changeset_ext(
        with => 'src',
        as   => sq(
            select   => 'c.id',
            from     => 'changes c',
            order_by => 'c.id ASC',
        ),
    );
    $sth->execute;
    my $sth_uuid2id = $db->xprepare(
        select => 'c.id',
        from   => 'changes c',
        where  => 'c.uuid = ?',
    );
    # TODO this is a development aide that will stop working when
    # we start deleting from changes_pending again.
    my $sth_terms = $db->xprepare(
        select => 'up.terms',
        from   => 'changes_pending up',
        where  => 'up.change_id = ?',
    );
    my ( $del, $add, $yellow, $reset ) =
      $self->colours( 'red', 'green', 'yellow', 'reset' );
    $self->start_pager;
    my $bad = 0;
    my @bad;
    while ( my $u = $sth->changeset_ext ) {
        my $uuid = delete $u->[0]->{uuid};
        my $yaml = Dump($u);
        my $sha1 = sha1_hex($yaml);
        next if $uuid eq $sha1;
        $bad++;
        $sth_uuid2id->execute($uuid);
        my $id = $sth_uuid2id->val;
        my $msg =
            $yellow
          . "c$id: "
          . ( $u->[$#$u]->{action_format} // '** undefined action_format **' )
          . $reset;
        if ( !$opts->{verbose} ) {
            push( @bad, $msg );
            next;
        }
        say $msg;
        $sth_terms->execute($id);
        my $terms = $sth_terms->val;
        my $diff = diff \$yaml, \$terms;
        $diff =~ s/^\-/$del-/mg;
        $diff =~ s/^\+/$add+/mg;
        say $diff;
    }
    return $self->err(
        'Check', "UUID mismatch errors: %d\n%s",
        $bad, '  ' . join( "\n  ", @bad )
    ) if $bad;
    print "UUIDs ok";
    return $self->ok('Check');
}
1;
__END__
=head1 NAME
=for bif-doc #devadmin
bif-check - check all changeset UUIDs
=head1 VERSION
0.1.4 (2014-10-27)
=head1 SYNOPSIS
    bif check [OPTIONS...]
=head1 DESCRIPTION
The B<bif-check> command reports on the differences between the YAML
created by various ON INSERT triggers, and the YAML/structure generated
by the C<changeset()> method of Bif::DBW::st.
This is a mostly a tool for developers.
=head1 ARGUMENTS & OPTIONS
=over
=item --verbose, -v
Display a diff of the changes_pending.terms value and the expected YAML
text. For this to have any effect the C<DELETE FROM changes_pending>
statement must be disabled in the changes_pending BEFORE UPDATE
trigger.
=back
=head1 SEE ALSO
L<bif>(1)
=head1 AUTHOR
Mark Lawrence E<lt>nomad@null.netE<gt>
=head1 COPYRIGHT AND LICENSE
Copyright 2014 Mark Lawrence <nomad@null.net>
This program is free software; you can redistribute it and/or modify it
under the terms of the GNU General Public License as published by the
Free Software Foundation; either version 3 of the License, or (at your
option) any later version.